1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
/*********************************************************************
This is an example for our nRF52 based Bluefruit LE modules
Pick one up today in the adafruit shop!
Adafruit invests time and resources providing this open source code,
please support Adafruit and open-source hardware by purchasing
products from Adafruit!
MIT license, check LICENSE for more information
All text above, and the splash screen below must be included in
any redistribution
*********************************************************************/
/* This sketches demontrates the Bluefruit.Advertising API(). When powered up,
* the Bluefruit module will start advertising for ADV_TIMEOUT seconds (by
* default 30 seconds in fast mode, the remaining time slow mode) and then
* stop advertising completely. The module will start advertising again if
* PIN_ADV is grounded.
*/
#include <bluefruit.h>
#define PIN_ADV A0
#define ADV_TIMEOUT 60 // seconds
void setup()
{
// configure PIN_ADV as input with a pullup (pin is active low)
pinMode(PIN_ADV, INPUT_PULLUP);
Serial.begin(115200);
while ( !Serial ) delay(10); // for nrf52840 with native usb
Serial.println("Bluefruit52 Advanced Advertising Example");
Serial.println("----------------------------------------\n");
Bluefruit.begin();
// Set max power. Accepted values are: -40, -30, -20, -16, -12, -8, -4, 0, 4
Bluefruit.setTxPower(4);
Bluefruit.setName("Bluefruit52");
// Set up and start advertising
startAdv();
Serial.println("Advertising is started");
}
void startAdv(void)
{
// Advertising packet
Bluefruit.Advertising.addFlags(BLE_GAP_ADV_FLAGS_LE_ONLY_GENERAL_DISC_MODE);
Bluefruit.Advertising.addTxPower();
Bluefruit.Advertising.addName();
/* Start Advertising
* - Enable auto advertising if disconnected
* - Interval: fast mode = 20 ms, slow mode = 152.5 ms
* - Timeout for fast mode is 30 seconds
* - Start(timeout) with timeout = 0 will advertise forever (until connected)
*
* For recommended advertising interval
* https://developer.apple.com/library/content/qa/qa1931/_index.html
*/
Bluefruit.Advertising.setStopCallback(adv_stop_callback);
Bluefruit.Advertising.restartOnDisconnect(true);
Bluefruit.Advertising.setInterval(32, 244); // in units of 0.625 ms
Bluefruit.Advertising.setFastTimeout(30); // number of seconds in fast mode
Bluefruit.Advertising.start(ADV_TIMEOUT); // Stop advertising entirely after ADV_TIMEOUT seconds
}
void loop()
{
// Only check pin when advertising has already stopped
if ( !Bluefruit.Advertising.isRunning() )
{
// Check if Pin is grounded
if ( digitalRead(PIN_ADV) == 0 )
{
Bluefruit.Advertising.start(ADV_TIMEOUT);
Serial.println("Advertising is started");
}
}
}
/**
* Callback invoked when advertising is stopped by timeout
*/
void adv_stop_callback(void)
{
Serial.println("Advertising time passed, advertising will now stop.");
}
|
